//-------------------------------------------------------------------//
//                                                                   //
// 			Prueba de sistema                            //
//								     //
//-------------------------------------------------------------------//

#include "../include/lang.inc"	/* tipos de datos nativos */
#include "../include/system.inc"/* libreria estandar */
print(x): system.print(x)	/* abreviatura para system.print(x) */

#include "aventuraParser.txt"	/* parser */

//-------------------------------------------------------------------//
//                                                                   //
//	               Modelo de mundo virtual                       //
//                                                                   //
//-------------------------------------------------------------------//

	/**********/
	/* Objeto */
	/**********/
	
	/* La abstraccion 'objeto' define la estructura basica de un objeto del */
	/* mundo virtual */

abstract objeto::object{
	nombre: 	abstract	// nombre del objeto
	descripcion: 	" No ves nada especial." // mensaje al examinar el objeto
	inventario:	null		// mensaje al hacer inventario de objetos
	mensaje:	null		// mensaje al examinar la estancia que contiene al objeto
	accion:    	null		// accion a ejecutar siempre que el objeto este presente
	
	//..................................................................
	// Representación del mundo virtual como un arbol de objetos
	//..................................................................
	
	var dentroDe:	lexicalParent	// objeto que contiene al actual
	var contiene:  	lexicalSons	// objetos contenidos dentro del actual
	
	moverA(x):			// mover el objeto a x desde su ubicacion actual
		if x!==null then
			if x.contiene===null then x.contiene=[self]
			else x.contiene=x.contiene::[self]
		let z=self.dentroDe.contiene,y=[],i in
			for i=0,i<z.length,i=i+1 do 
				if z[i]!==self then y=y::[z[i]]
			self.dentroDe.contiene=y
		dentroDe=x
			
	borrar:				// borrar el objeto del mundo virtual
		moverA(null)
}

	/*************/
	/* Decorado  */
	/*************/
	
	/* Un decorado es un objeto sobre el que no se puede realizar ninguna accion */
	/* no contemplativa */

abstract decorado::objeto{		
}
	
	/**************/
	/* Habitacion */
	/**************/
	
	/* Una habitacion es un tipo especial de decorado, en el que se puede mover el */
	/* protagonista */
		
abstract habitacion::decorado{
	salidaSur:	null
	salidaNorte:	null
	salidaEste:	null
	salidaOeste:	null
	salidaEntrar:	null
	salidaSalir:	null
}
	
	/**********/
	/* Comida */
	/**********/
	
	/* Comida es cualquier objeto que el protagonista de la aventura pueda absorver */

abstract comida::objeto{	
	calorias:	abstract
	alcomer:	" Esto... que rico!"
	descripcion:	" Que mas da que pinta tenga... es comida!"
}


//-------------------------------------------------------------------//
//                                                                   //
//	                   Mundo virtual                             //
//                                                                   //
//-------------------------------------------------------------------//

/***********************************************************************/
/* El protagonista                                                     */
/***********************************************************************/

protagonista::decorado{
	nombre:		"yo"
	descripcion:	" Que guapo eres."
	var calorias:	1

	var ultimasCalorias: 0
	accion:
		let i=protagonista.calorias,j=ultimasCalorias in
			if i-j>0 then
				if j<3 and i>=3 then 
					print (" Sientes como creces a medida 
						que asimilas el jugo vital.\n")
				if j<6 and i>=6 then 
					print (" Sientes como creces. Asomandote 
						al borde del cubo puedes ver parte 
						de la cocina.\n")
				if j<12 and i>=12 then 
					print (" Sientes como creces. 
						Te sientes fuerte.\n")
				ultimasCalorias=i
}


/***********************************************************************/
/* El mundo del protagonista                                           */
/***********************************************************************/

mundo::decorado{
 nombre: "mundo"
	
/***********************************************************************/
/* (1) El origen de la vida                                            */
/***********************************************************************/

 cuboBasura::habitacion{
	nombre:		"cubo"
	descripcion:	" Esta oscuro y calentito aqui dentro.\n\n
			  Es un cubo de basura.\n\n
			  Un cubo de basura donde capas y capas de bazofia acumulada durante 
			anhos por un grupo de estudiantes se han sobrecalentado, apelmazado, 
			enfriado, descongelado, y recalentado generando una pasta de detritos 
			rica en nutrientes; un nuevo caldo primigenio afectado  
			por las severas radiaciones del microondas que ha alterado su estructura 
			interna y ha creado... vida!"
	salidaSalir:
			if (protagonista.calorias>=6) then cocina
			else null
				
	comida{
		var calorias:	1
		nombre:		["basura","tropezones"]
		inventario:	"unos tropezones de basura"
		descripcion:	" Tropezones de basura verde y apestosa."
		alcomer:	" Sientes como tu pequenho cuerpo grita 
				entero de placer ante tan suculento bocado."
	}
	comida{
		var calorias:	1
		nombre:		["cachito","bazofia"]
		inventario:	"un cachito de bazofia"
		descripcion:	" Un cachito de bazofia, rezumando jugo."
		alcomer:	" Asimilas poco a poco el jugo y luego el trozo entero de bazofia
				sucia y apestosa, relamiendote de puro placer."			
	}	
	
	comida{
		var calorias:	1
		nombre:		["masa","trocito"]
		inventario:	"un trocito de masa gris"
		descripcion:	" Un trocito de masa que dice: comeme!"
		alcomer:	
			armazon.moverA(cubobasura)
			" Deglutes y deglutes. Llenas tus carrillos de rica 
			basura -burp!- hasta que solo queda el esqueleto de 
			un antiguo armazon de comida rapida"
	}

	excrementos::comida{
		var calorias:	1
		nombre:		["excrementos","excremento"]
		descripcion:	" Rodean al pate formando montanhitas"
		alcomer:	" Apartas el pate y te comes los excrementos que lo rodean."
	}	
	
	comida{
		var calorias:	0
		nombre:		["pedacito","pate"]
		inventario:	
			if (excrementos.calorias==0) then "un pedacito de pate"
			else "un pedacito de pate rodeado de excrementos"
		descripcion:	" Pate frances a las finas hierbas."
		alcomer:	" Pate? que asco!!"
	}
	
	decorado{		
		nombre:		["lata","conserva"]
		inventario:	"una lata de conserva vacia"
		descripcion:	
			if larva.calorias!=0 then
				larva.moverA(cubobasura)
				" Hay una larva de mosca retorciendose dentro de la lata"
			else " Una lata vacia de chipirones en su tinta"
	}
	
	comida{
		var calorias:	3
		nombre:		if parser.turno>=10 then "cucaracha" else ""
		descripcion:	" Una juguetona cucaracha, rebosante de jugos vitales."	
		alcomer:	" Burp!"
		accion:		
			if parser.turno==10 then 
				" Puedes ver una cucaracha 
				revoloteando entre la comida"
			else null
		mensaje:	
			if parser.turno>10 then 
				" Una cucaracha revolotea 
				entre la comida."
			else null
	}

 }

 armazon::decorado{
	nombre:		["armazon","comida"]
	inventario:	"un armazon de comida rapida"
 }
 
 larva::comida{
		var calorias: 	2
		nombre:		"larva"
		inventario:	"una larva"
		descripcion:	" Una larva blanca y regordeta."
		alcomer:	" Una larva siempre es un bocado tierno..."	
 }
		 
/***********************************************************************/
/* (2) La cocina                                                       */
/***********************************************************************/
	
 cocina::habitacion{
	nombre:		"cocina"
	descripcion:	" Estas en la cocina.\n\n Aunque tu no lo sabes, una inesperada
			visita familiar ha provocado una limpieza a fondo. La vajilla
			esta limpia y puesta a secar, los suelos fregados y la encimera 
			reluciente.\n
			 En una esquina ves el cubo de la basura, que evoca recuerdos de 
			tu infancia.\n\n
			 Hacia el norte comienza el pasillo."
	salidanorte:	pasillosur
	salidaentrar:	cubobasura
	
	decorado{
		nombre:		["vajilla","platos","vasos"]
		descripcion:	" La vajilla de la generacion inmediatamente anterior a los 
				habitantes de la casa, decorada con motivos florales azules 
				sobre fondo blanco"
	}
	
	decorado{		
		nombre:		["suelos","suelo"]
		descripcion:	
				if pegote.calorias!=0 then
					pegote.moverA(cocina)
					" Eh, aqui hay un pegote sin limpiar!"
				else " Limpios como una patena."
	}			
	
	decorado{
		nombre:		"microondas"
		descripcion:	" Limpio, como el resto de la cocina."
	}
	
 }

 pegote::comida{
	var calorias:	1
	nombre:		["pegote","grasa"]
	inventario:	"un pegote en el suelo"
	descripcion:	" Un viejo pegote de grasa, duro y pegajoso. "
 }

/***********************************************************************/
/* (3) El pasillo                                                      */
/***********************************************************************/

 pasillosur::habitacion{
	nombre:		"pasillo"
	descripcion:	" Estas en la parte sur del pasillo. Al sur queda la
			  cocina, al oeste el banho y al este el salon."
	salidasur:	cocina
	salidaoeste: 	banho
	salidaeste:	salon
	salidanorte:	pasillonorte
 }

 pasillonorte::habitacion{
	nombre:		"pasillo"
	descripcion:	" Estas en la parte norte del pasillo. Al este y al
			  norte estan las habitaciones de los habitantes de la
			  casa y al oeste, rodeado por un
			  marco de madera de pino, la puerta que conduce al
			  mundo de los humanos."
	salidasur:	pasillosur
	salidaoeste: 	mundoexterior
	salidaeste:	habitaeste
	salidanorte:	habitanorte

	comida{
		var calorias:	1
		nombre:		["pelusas","pelusa"]
		inventario:	"algunas pelusas"
		descripcion: 	" Basicamente una mezcla de polvo, pelo y grasa"
		alcomer:	" Nunca te han gustado mucho las pelusas, pero te las comes."
	}
 }

/***********************************************************************/
/* (4) El salon                                                        */
/***********************************************************************/

 salon::habitacion{
	nombre:		"salon"
	descripcion:	" El salon es una estancia amplia, aunque poco aprovechada. Las
			persianas estan bajadas y la unica luz de la sala es la del televisor, 
			que nadie mira. Rodeando el televisor hay dos tresillos y un sofa con
			un alfombra en medio."
	salidaoeste:	pasillosur
	salidasalir:	pasillosur

	decorado{
		nombre:		"alfombra"
		descripcion:	" No hay nada que llevarse a la boca en esta alfombra."
	}
	
	decorado{
		nombre:		"tresillo"
	}
	
	decorado{
		nombre:		"sofa"
	}
	
	decorado{
		nombre:		"persianas"
		descripcion:	" Que esperas encontrar en unas persianas?"
	}
	
	decorado{
		nombre:		"persiana"
		descripcion:	" Que esperas encontrar en una persiana?"
	}
	
	decorado{
		nombre:		["televisor","television","tele"]
		descripcion:	" La television no emite ningun sonido. Unos humanos 
				estupidos gesticulan en la pantalla."
	}
	
	humano::comida{		
		var calorias:	15
		nombre:		"humano"
		descripcion:	" Un humano gordito y con patillas."
		mensaje:	" En el sofa duerme un humano."
		accion:		
			let i=parser.turno%10 in
				if (i==1) then " El humano da unas vueltas en la cama."
				else if (i==4) then " El humano se rasca las axilas."
				else if (i==8) then " El humano empieza a roncar."
				else if (i==0) then " El humano deja de roncar."
				else ""
		alcomer:	
			huesos.moverA(salon)
			" Extiendes la masa de tu cuerpo sobre el humano y 
			empiezas a succionar su flujo. El humano 
			se levanta sorprendido; intenta deshacerse de ti, pero 
			tras un breve forcejeo, se desmaya. Una vez en el suelo, 
			chupeteas con delicia su masa hasta dejar un saco 
			de huesos mondos y lirondos."
	}
	
	decorado{
		nombre:		"botellas"
		inventario:	"unas botellas"
		descripcion:	" Botellas vacias de cerveza, vino y licor cafe."
	}
	
	comida{
		var calorias:	1
		nombre:		["patatas","papas"]
		inventario:	"unas patatas fritas"
		descripcion:	" Restos de patatas fritas."
	}
	
	decorado{
		nombre:		"revista"
		inventario:	"una revista"
		descripcion:	" Un ejemplar de prensa del corazon. Los humanos 
				a esto le llaman comidilla pero para ti no tiene 
				ningun valor energetico."		
	}
	
	decorado{
		nombre:		"carpeta"
		inventario:	"una carpeta"
		descripcion:	" Una carpeta llena de apuntes."
	}	
 }
  
 carne::comida{
	var calorias:	2
	nombre: 	"carne"
	inventario:	"un trozo de carne humana"
	descripcion:	" Roja y tierna carne de humano."
	alcomer:	" Yum!"
 }
 
 huesos::decorado{
	nombre:		["cadaver","huesos"]
	inventario:	"el cadaver de un humano"
	descripcion:	
		if carne.calorias!=0 then
			carne.moverA(salon)
			" Aun queda un cachito de carne pegado a los huesos."
		else " Los huesos mondos y lirondos de un humano."
 }
 
/***********************************************************************/
/* (4) El banho                                                        */
/***********************************************************************/

 banho::habitacion{
	nombre:		"banho"
	descripcion:	" El banho de la casa se compone de una ducha de
			pie, una pileta y un vater. Parece no haberse lavado 
			nunca. Y probablemente asi sea."
	salidaeste:	pasillosur
	salidasalir:	pasillosur
	
	decorado{		
		nombre:		"vater"
		descripcion:	
				if mierda.calorias!=0 then
					mierda.moverA(banho)
					" Estos vateres son bastante limpios de por si, el 
					agua corriendo y el cloro hacen su trabajo. Menos 
					mal que no se puede decir lo mismo de los duenhos;
					descubres un trocito de mierda pegado a la parte 
					inferior de la taza. Aparte de eso, nada."
				else
					" Estos vateres son bastante limpios de por si, el agua corriendo y el cloro hacen su trabajo."
	}
	
	decorado{
		nombre:		"pileta"
		descripcion:	" Un grifo, mucha porcelana y un desague. Aburrido."
	}
	
	comida{
		var calorias: 	0
		nombre:		"jabon"
		inventario:	"un trozo de jabon"
		descripcion:	" No hay nada mas deprimente para una basura que la vista
				de un trozo de jabon."
		alcomer:	" Ni de broma."
	}
	
	comida{
		var calorias: 	0
		nombre:		["champu","frasco"]
		inventario:	"un frasco de champu al huevo"
		descripcion:	" Si pudieras separar el huevo, y el huevo fuera huevo
				podrido... pero no."
		alcomer:	" Ni en un millon de anhos."
	}
	
	decorado{
		nombre:		"ducha"
		descripcion:	" De un grifo caen gotas de agua, y parece 
				regularse con dos rosquitas que salen de la pared. No tiene 
				mucho interes para ti"
	}
	
	decorado{
		nombre:		"desague"
		inventario:	"un desague en el suelo"
		descripcion:	" Te encantaria darte un paseo hasta la alcantarilla. Sin 
				embargo, una rejilla lo impide."
	}
	
 }
 
 mierda::comida{
	var calorias:	1
	nombre:		"mierda"
	descripcion:	" Mierda marroncita."
	inventario:	"un trocillo de mierda pegado a la taza del vater"
 }

/***********************************************************************/
/* (5) La habitacion                                                   */
/***********************************************************************/

 habitaEste::habitacion{
	nombre:		"habitacion"
	descripcion:	" Se trata de una habitacion pequenha y poco decorada
			excepto por algunos posters, y por las marcas de otros
			posters anteriores, y de otros todavia anteriores."
	salidaoeste:	pasillonorte
	salidasalir:	pasillonorte

	decorado{
		nombre:		["colchon","cama"]
		inventario:	"un colchon -a forma de cama-"
		descripcion:	" Las sabanas huelen a suciedad, pero no vas a poder sacar
				nada de ellas."
	}
	
	decorado{
		nombre:		"mesa"
		inventario:	"una mesa de estudio"
		descripcion:	" Aqui solo hay papelotes y algunos boligrafos. "
	}
	
	decorado{
		nombre:		"silla"
		inventario:	"una silla"
		descripcion:	" Cuatro patas, y un tablon. Todo lo que necesita
				un estudiante."
	}
	
	decorado{
		nombre:		["cadena","minicadena"]
		inventario:	"una cadena de musica"
		descripcion:	" Un modelo japones. Barato."
	}
	
	decorado{
		nombre:		["cintas","musica","pila"]
		inventario:	"una pila de cintas de musica"
		descripcion:	" Todo rock. Odias el rock."
	}	
	
	decorado{		
		nombre:		"cenicero"
		inventario:	"un cenicero"
		descripcion:	
			let i in
				print(" El cenicero ")
				if colillas.calorias!=0 or hueso.calorias!=0 or chicle.calorias!=0 then
					print("contiene ")
					if colillas.calorias!=0 then
						print(colillas.inventario)
						colillas.moverA(habitaeste)
						if hueso.calorias!=0 and chicle.calorias!=0 then
							print(", ")
						else if hueso.calorias!=0 or chicle.calorias!=0 then
							print(" y ")
					if hueso.calorias!=0 then
						hueso.moverA(habitaeste)
						print(hueso.inventario)
						if chicle.calorias!=0 then print(" y ")
					if chicle.calorias!=0 then
						print(chicle.inventario)
						chicle.moverA(habitaeste)
				else print("esta vacio.")
				""
	}
	
	comida{
		var calorias: 	3
		nombre:		["restos","chettos","fritos","papadeltas","pelotazos","comida"]
		inventario:	"algunos restos de comida al pie de la cama"
		descripcion:	" Yum! Restos de chettos, fritos, papa deltas y 
				pelotazos!!"
		alcomer:	" Gloria!"
	}
 }

 colillas::comida{
	var calorias:	1
	nombre:		"colillas"
	inventario:	"unas colillas"
	descripcion:	" Tabaco, papel, y aditivos de baja y mas baja calidad."
	alcomer:	" Las colillas no alimentan mucho, pero va."
 }
 hueso::comida{
	var calorias:	1
	nombre:		"hueso"
	inventario:	"un hueso de melocoton"
	descripcion:	" Despues de varios meses de reposar en el cenicero, 
			esta en su perfecto punto de maduracion."
	alcomer:	" Asimilas el hueso de melocoton del cenicero
			sin ningun pudor."
 }

 chicle::comida{
	var calorias:	1
	nombre:		"chicle"
	inventario:	"un chicle"
	descripcion:	" Un chicle de menta, con un recubrimiento de ceniza."
	alcomer:	" Aunque te desagrada el sabor a menta, 
			absorves facilmente la goma, y la ceniza tampoco 
			te sienta mal."	
 }
 
/***********************************************************************/
/* (6) La otra habitacion                                              */
/***********************************************************************/

 habitaNorte::habitacion{
	nombre:		"habitacion"
	descripcion:	" Estas en una habitacion pequenha, de color verde pistacho.\n
			 La habitacion esta vacia a excepcion de un armario -cerrado-, una 
			 mesita de estudio y una cama."
	salidasur:	pasillonorte
	salidasalir:	pasillonorte

	decorado{
		nombre:		"mesita"
		descripcion:	" Autentica madera de pino asturiano."
	}
	
	decorado{
		nombre:		"armario"
		descripcion:	" Es un armario y esta cerrado."
	}
	
	humano::comida{
		var calorias:	12
		nombre:		"humana"
		descripcion:	" Siempre te han dado grima esos humanos."
		mensaje:	" En la cama duerme una humana."
		accion:		let i=parser.turno%10 in
					if (i==1) then " La humana da unas vueltas en la cama."
					else if (i==4) then " La humana se rasca las axilas."
					else if (i==8) then " La humana empieza a roncar."
					else if (i==0) then " La humana deja de roncar."
					else ""
		alcomer:	
				huesos2.moverA(habitanorte)
				" Con emocion, recubres el cuerpo de la humana y empiezas a
				asimilar su masa. Aprovechando que esta profundamente dormida y
				narcotizada por los excesos nocturos no se despierta durante 
				la merendola. Te deleitas a placer asimilando sus 
				flujos vitales."
	
	}
	
	decorado{
		nombre:		"cama"
		descripcion:	
				if (humano.calorias!=0) then 
					" La cama se dobla bajo el peso del humano."
				else if (bocata.calorias!=0) then
					bocata.moverA(habitanorte)
					" Aqui hay un trozo de bocadillo, 
					que debia estar ocultando la humana."
				else " Aqui no hay nada de interes."
		
		hidden bocata::comida{
			var calorias:	2
			nombre:		"bocadillo"
			inventario:	"un trozo de bocadillo"
			descripcion:	" Un montadito de pechuga bastante reseso."
			alcomer:	" El montado de pechuga pasa facilmente a tu organismo."
		}
	}

 }

 huesos2::decorado{
	nombre:		"huesos"
	inventario:	"un punhado de huesos"
	descripcion:	" Son los huesos de una humana."
 }	

/***********************************************************************/
/* (7) El mundo exterior                                               */
/***********************************************************************/

// La aventura acaba al salir al mundo exterior

 mundoExterior::habitacion{
	nombre: ["portal","puerta"]
	descripcion: 
	    let tam=protagonista.calorias in
		
		parser.fin=true
		
		print(" Tomando forma de filloa, te deslizas por debajo del marco 
		      de la puerta. Sediento de jugos vitales, avanzas por el 
		      descansillo, donde una humana limpia la escalera.\n")

		if (tam<=10) then 
			print(" Extranhada por la presencia de una inadvertida pelota de 
			      pus, saca una botella de lejia que vierte 
			      sobre tu cuerpo. Mientras te consumes en tu agonia 
			      eres frotado, desinfectado y erradicado de esta 
			      vida por una senhora de la limpieza.")
		else if (tam<=20) then
			print(" Extranhada por la presencia de una filloa de 
			      pus, saca una botella de lejia que vierte 
			      sobre tu cuerpo. Mientras te consumes en agonia 
			      ella intenta desinfectarte y erradicarte de esta 
			      vida. Consigues atacarla y escapar a la carrera. Sales 
			      tras de ella, pero los gritos han alarmado a las vecinas, 
			      que armadas de todo tipo de artilugios de tortura consiguen 
			      recucirte en el armario del contador de la luz y acabar 
			      con tu efimera vida.")
		else if (tam<51) then
			print(" Extranhada por la presencia de un charco de 
			      pus, saca una botella de lejia que vierte 
			      sobre tu cuerpo. Mientras te retuerces de dolor, 
			      ella grita y cae al suelo desmayada.\n
			       El ruido alarma a los vecinos, 
			      que salen al pasillo preguntandose lo que pasa. Al ver 
			      a la humana muerta, cunde el panico en el edificio.\n
			       Aprovechas la confusion para escapar y llegar a la alcantarilla 
			      mas cercana, donde te recuperas de las heridas. Alli  
			      conoces a otra bella basurilla; con el tiempo sientas 
			      la cabeza y fundas una bella familia, dedicando 
			      tus energias a tu nuevo hogar y aparcando las ansias de 
			      venganza y dominacion del mundo.")
		else 
			print(" Extranhada por la presencia de un gran charco de 
			      pus que se arrastra hacia ella, queda paralizada por el miedo.\n
			       Absorves la humana que muere entre tremendos gritos de agonia, 
			      que alarman a los vecinos. 
			       Al instante cunde el panico, provocando una estampida por las 
			      escaleras. Consigues dar caza a algunos de los humanos mas rezagados 
			      absorviendo su flujo vital.\n
			       A cada minuto eres fuerte. Absorves todo lo que esta a tu 
			      alcance -restos de comida, suciedad, pequenhos animales...-. 
			      Cuando sales al exterior, ya no eres un ser pequenho salido 
			      de una modesta basura.\n Contento contigo mismo, te deslizas 
			      calle abajo.")

		print("\n\n En esta aventura has conseguido ":protagonista.calorias:" puntos de un total de 51 consiguiendo el titulo de ")
		
		if (tam<=10) then
			print("moco fracasado")
		else if (tam<=20) then
			print("filloa peleona")
		else if (tam<51) then
			print("bazofia entranhable")
		else 
			print("gran emperador de una nueva era de mierda")
		".\n"
 }

/***********************************************************************/

} //mundo
			
/***********************************************************************/
/* Bucle principal                                                     */
/***********************************************************************/

//...................................................................................
// MAIN                                                           
//...................................................................................

main:
	parser.turno=1
	protagonista.dentroDe=mundo.cuboBasura
	protagonista.contiene=null
	
	print("\n Primero no sentias nada, luego, poco a poco, se fue haciendo la luz...\n\n")
	gramatica.mirar.accion([])
	
	while not parser.fin do
		parser.parse()
	
//-------------------------------------------------------------------//
//                                                                   //
//	          Extra: Solucion de la aventura                     //
//                                                                   //
//-------------------------------------------------------------------//
/*
	
			comer basura		     
			comer bazofia
			comer excrementos
			comer masa
			mirar lata
			comer larva
			esperar
			esperar
			esperar
			esperar
			comer cucaracha
			salir / ir a cocina
			mirar suelo
			comer pegote
			norte
			norte
			comer pelusas
			sur
			oeste
			mirar vater
			comer mierda
			salir
			norte
			norte
			comer humana
			mirar cama
			comer bocadillo
			sur
			este
			comer restos
			mirar cenicero
			comer colillas
			comer hueso
			comer chicle
			oeste
			sur
			este
			comer patatas
			comer humano
			mirar cadaver
			comer carne
			salir 
			norte
			oeste
*/